diff --git a/Makefile.am b/Makefile.am
index 1e2c26f5ac..9c27113673 100644
--- a/Makefile.am
+++ b/Makefile.am
@@ -82,6 +82,7 @@ MODULES =					\
   guix/discovery.scm				\
   guix/bzr-download.scm            		\
   guix/git-download.scm				\
+  guix/git-repo-download.scm			\
   guix/hg-download.scm				\
   guix/swh.scm					\
   guix/monads.scm				\
@@ -176,6 +177,7 @@ MODULES =					\
   guix/build/bzr.scm				\
   guix/build/copy-build-system.scm		\
   guix/build/git.scm				\
+  guix/build/git-repo.scm			\
   guix/build/hg.scm				\
   guix/build/glib-or-gtk-build-system.scm	\
   guix/build/gnu-bootstrap.scm			\
diff --git a/guix/build/git-repo.scm b/guix/build/git-repo.scm
new file mode 100644
index 0000000000..571a022224
--- /dev/null
+++ b/guix/build/git-repo.scm
@@ -0,0 +1,74 @@
+;;; GNU Guix --- Functional package management for GNU
+;;; Copyright © 2014, 2016, 2019 Ludovic Courtès <ludo@gnu.org>
+;;; Copyright © 2020 Danny Milosavljevic <dannym@scratchpost.org>
+;;;
+;;; This file is part of GNU Guix.
+;;;
+;;; GNU Guix is free software; you can redistribute it and/or modify it
+;;; under the terms of the GNU General Public License as published by
+;;; the Free Software Foundation; either version 3 of the License, or (at
+;;; your option) any later version.
+;;;
+;;; GNU Guix is distributed in the hope that it will be useful, but
+;;; WITHOUT ANY WARRANTY; without even the implied warranty of
+;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+;;; GNU General Public License for more details.
+;;;
+;;; You should have received a copy of the GNU General Public License
+;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
+
+(define-module (guix build git-repo)
+  #:use-module (guix build utils)
+  #:use-module (srfi srfi-34)
+  #:use-module (ice-9 format)
+  #:export (git-repo-fetch))
+
+;;; Commentary:
+;;;
+;;; This is the build-side support code of (guix git-repo-download).  It
+;;; allows a Git-repo repository to be cloned and checked out at a specific
+;;; revision.
+;;;
+;;; Code:
+
+(define* (git-repo-fetch manifest-url manifest-revision directory
+                    #:key (git-repo-command "git-repo"))
+  "Fetch packages according to the manifest at MANIFEST-URL with
+MANIFEST-REVISION.  MANIFEST-REVISION must be either a revision
+or a branch.  Return #t on success, #f otherwise."
+
+  ;; Disable TLS certificate verification.  The hash of the checkout is known
+  ;; in advance anyway.
+  (setenv "GIT_SSL_NO_VERIFY" "true")
+
+  (mkdir-p directory)
+
+  (guard (c ((invoke-error? c)
+             (format (current-error-port)
+                     "git-repo-fetch: '~a~{ ~a~}' failed with exit code ~a~%"
+                     (invoke-error-program c)
+                     (invoke-error-arguments c)
+                     (or (invoke-error-exit-status c) ;XXX: not quite accurate
+                         (invoke-error-stop-signal c)
+                         (invoke-error-term-signal c)))
+             (delete-file-recursively directory)
+             #f))
+    (with-directory-excursion directory
+      (invoke git-repo-command "init" "-u" manifest-url "-b" manifest-revision
+              "--depth=1")
+      (invoke git-repo-command "sync" "-c" "--fail-fast" "-v" "-j" "3")
+
+      ;; Delete vendor/**/.git, system/**/.git, toolchain/**/.git,
+      ;; .repo/**/.git etc since they contain timestamps.
+      (for-each delete-file-recursively
+       (find-files "." "^\\.git$" #:directories? #t))
+
+      ;; Delete git state directories since they contain timestamps.
+      (for-each delete-file-recursively
+       (find-files ".repo" "^.*\\.git$" #:directories? #t))
+
+      ;; This file contains timestamps.
+      (delete-file ".repo/.repo_fetchtimes.json")
+      #t)))
+
+;;; git-repo.scm ends here
diff --git a/guix/git-repo-download.scm b/guix/git-repo-download.scm
new file mode 100644
index 0000000000..27f7f1fa8d
--- /dev/null
+++ b/guix/git-repo-download.scm
@@ -0,0 +1,158 @@
+;;; GNU Guix --- Functional package management for GNU
+;;; Copyright © 2014, 2015, 2016, 2017, 2018, 2019 Ludovic Courtès <ludo@gnu.org>
+;;; Copyright © 2017 Mathieu Lirzin <mthl@gnu.org>
+;;; Copyright © 2017 Christopher Baines <mail@cbaines.net>
+;;; Copyright © 2020 Jakub Kądziołka <kuba@kadziolka.net>
+;;; Copyright © 2020 Danny Milosavljevic <dannym@scratchpost.org>
+;;;
+;;; This file is part of GNU Guix.
+;;;
+;;; GNU Guix is free software; you can redistribute it and/or modify it
+;;; under the terms of the GNU General Public License as published by
+;;; the Free Software Foundation; either version 3 of the License, or (at
+;;; your option) any later version.
+;;;
+;;; GNU Guix is distributed in the hope that it will be useful, but
+;;; WITHOUT ANY WARRANTY; without even the implied warranty of
+;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+;;; GNU General Public License for more details.
+;;;
+;;; You should have received a copy of the GNU General Public License
+;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
+
+(define-module (guix git-repo-download)
+  #:use-module (guix gexp)
+  #:use-module (guix store)
+  #:use-module (guix monads)
+  #:use-module (guix records)
+  #:use-module (guix packages)
+  #:use-module (guix modules)
+  #:autoload   (guix build-system gnu) (standard-packages)
+  #:use-module (git) ; FIXME Remove
+  #:use-module (ice-9 match)
+  #:use-module (ice-9 vlist)
+  #:use-module (srfi srfi-1)
+  #:use-module (srfi srfi-34)
+  #:use-module (srfi srfi-35)
+  #:export (git-repo-reference
+            git-repo-reference?
+            git-repo-reference-mainfest-url
+            git-repo-reference-revision
+
+            git-repo-fetch
+            git-repo-version
+            git-repo-file-name))
+
+;;; Commentary:
+;;;
+;;; An <origin> method that fetches a specific commit from a git-repo
+;;; repository.
+;;; The repository's manifest (URL and revision) can be specified with a
+;; <git-repo-reference> object.
+;;;
+;;; Code:
+
+(define-record-type* <git-repo-reference>
+  git-repo-reference make-git-repo-reference
+  git-repo-reference?
+  (manifest-url        git-repo-reference-manifest-url)
+  (manifest-revision   git-repo-reference-manifest-revision))
+
+(define (git-repo-package)
+  "Return the default git-repo package."
+  (let ((distro (resolve-interface '(gnu packages android))))
+    (module-ref distro 'git-repo)))
+
+(define* (git-repo-fetch ref hash-algo hash
+                    #:optional name
+                    #:key (system (%current-system)) (guile (default-guile))
+                    (git-repo (git-repo-package)))
+  "Return a fixed-output derivation that fetches REF, a <git-repo-reference>
+object.  The output is expected to have recursive hash HASH of type
+HASH-ALGO (a symbol).  Use NAME as the file name, or a generic name if #f."
+  ;; TODO: Remove.
+  (define inputs
+    (standard-packages))
+
+  (define zlib
+    (module-ref (resolve-interface '(gnu packages compression)) 'zlib))
+
+  (define guile-json
+    (module-ref (resolve-interface '(gnu packages guile)) 'guile-json-3))
+
+  (define gnutls
+    (module-ref (resolve-interface '(gnu packages tls)) 'gnutls))
+
+  (define config.scm
+    (scheme-file "config.scm"
+                 #~(begin
+                     (define-module (guix config)
+                       #:export (%libz))
+
+                     (define %libz
+                       #+(file-append zlib "/lib/libz")))))
+
+  (define modules
+    (cons `((guix config) => ,config.scm)
+          (delete '(guix config)
+                  (source-module-closure '((guix build git-repo)
+                                           (guix build utils)
+                                           (guix build download-nar))))))
+
+  (define build
+    (with-imported-modules modules
+      (with-extensions (list guile-json gnutls)   ;for (guix swh)
+        #~(begin
+            (use-modules (guix build git-repo)
+                         (guix build utils)
+                         (guix build download-nar)
+                         (ice-9 match))
+
+            ;; The 'git submodule' commands expects Coreutils, sed,
+            ;; grep, etc. to be in $PATH.
+            (set-path-environment-variable "PATH" '("bin")
+                                           (match '#+inputs
+                                             (((names dirs outputs ...) ...)
+                                              dirs)))
+
+            (setvbuf (current-output-port) 'line)
+            (setvbuf (current-error-port) 'line)
+
+            (or (git-repo-fetch (getenv "git-repo manifest-url")
+                                (getenv "git-repo manifest-revision")
+                                #$output
+                                #:git-repo-command
+                                (string-append #+git-repo "/bin/repo"))
+                (download-nar #$output))))))
+
+  (mlet %store-monad ((guile (package->derivation guile system)))
+    (gexp->derivation (or name "git-repo-checkout") build
+
+                      ;; Use environment variables and a fixed script name so
+                      ;; there's only one script in store for all the
+                      ;; downloads.
+                      #:script-name "git-repo-download"
+                      #:env-vars
+                      `(("git-repo manifest-url" .
+                         ,(git-repo-reference-manifest-url ref))
+                        ("git-repo manifest-revision" .
+                         ,(git-repo-reference-manifest-revision ref)))
+                      #:leaked-env-vars '("http_proxy" "https_proxy"
+                                          "LC_ALL" "LC_MESSAGES" "LANG"
+                                          "COLUMNS")
+                      #:system system
+                      #:local-build? #t           ;don't offload repo cloning
+                      #:hash-algo hash-algo
+                      #:hash hash
+                      #:recursive? #t
+                      #:guile-for-build guile)))
+
+(define (git-repo-version version revision)
+  "Return the version string for packages using git-repo-download."
+  (string-append version "-" (string-join (string-split revision #\/) "_")))
+
+(define (git-repo-file-name name version)
+  "Return the file-name for packages using git-repo-download."
+  (string-append name "-" version "-checkout"))
+
+
